【Arduino 动手做】ESP32 + BaseCam 蓝牙云台控制 简单

/*
Elation Sports Technologies LLC
Austin Allen
24 Jun 2024

BaseCam ESP32-S3 BLE Client/Master Code

The Client/Master ESP32 constantly reads joystick values values and
sends them out over BLE. The Slave ESP32 receives those 3 x integers
and sends corresponding serial commands to the SimpleBCG using the
BaseCam Serial API.

The Peripheral/slave ESP32 is running a PlatformIO project code
in order to utilize the most up-to-date Basecam Serial API.
That code is modified from the MimicControl Arduiuno example on
the BaseCam Github:
https://github.com/basecamelectronics/sbgc32-serial-api/tree/master/examples/Arduino/MimicControl

*/

#include <BLEDevice.h>

bool serial_debug_output_bool = true;

static String targetDeviceName = "ESP32_S3_BLE"; //Set this string to the name you assigned to the slave ESP32 in its code.
static BLERemoteCharacteristic* pTxCharacteristic;

// Master ESP32 UUIDs (update to match the slave ESP32)
static BLEUUID serviceUUID("4fafc201-1fb5-459e-8fcc-c5c9c331914b");
static BLEUUID charUUID("beb5483e-36e1-4688-b7f5-ea07361b26a8");

// Callback function to handle BLE notifications, i.e. the stuff coming back from the Peripheral/Slave ESP32.
// For this project, there isn't anything coming back from the Peripheral/Slave ESP32.
class MyCallbacks : public BLECharacteristicCallbacks {
    //Just print out any feedback that gets sent back from the slave ESP32.
    void onRead(BLECharacteristic* pCharacteristic) {
      0;
      //Serial.print("Received data: ");
      //Serial.println(pCharacteristic->getValue().c_str());
    }
};

//Joystick-related variables
//Pin definitions
const int pin_joy_x = 4;
const int pin_joy_y = 5;
const int pin_joy_z = 6;
int joystick_initial_x = 0; //Initial readings
int joystick_initial_y = 0;
int joystick_initial_z = 0;
int joystick_value_x = 0;
int joystick_value_y = 0;
int joystick_value_z = 0;
int joystick_deadzone_x = 30;
int joystick_deadzone_y = 30;
int joystick_deadzone_z = 30;

String BLE_data_to_send = "0,0,0";
bool device_found_bool = false;

String output_text = "";

void grab_initial_readings(){
  joystick_initial_x = analogRead(pin_joy_x);
  joystick_initial_y = analogRead(pin_joy_y);
  joystick_initial_z = analogRead(pin_joy_z);
}

void read_joysticks(){
  joystick_value_x = analogRead(pin_joy_x) - joystick_initial_x;
  joystick_value_y = analogRead(pin_joy_y) - joystick_initial_y;
  joystick_value_z = analogRead(pin_joy_z) - joystick_initial_z;
  if (abs(joystick_value_x) < joystick_deadzone_x){
    joystick_value_x = 0;
  }
  if (abs(joystick_value_y) < joystick_deadzone_y){
    joystick_value_y = 0;
  }
  if (abs(joystick_value_z) < joystick_deadzone_z){
    joystick_value_z = 0;
  }

  ////Serial.println(String(joystick_value_x) + "," + String(joystick_value_y) + "," + String(pin_joy_z));
}

void setup() {

  if (serial_debug_output_bool){
    Serial.begin(115200);
    while(!Serial){
      0;
    }
    Serial.println("Serial debug communication established.");
  }

  //Joystick pins
  pinMode(pin_joy_x,INPUT);
  pinMode(pin_joy_y,INPUT);
  pinMode(pin_joy_z,INPUT);

  grab_initial_readings();

  //Look for the slave ESP32 over BLE.
  output_text = "Searching: " + String(targetDeviceName);
  if (serial_debug_output_bool) Serial.println("Searching for ESP32 with device name: " + String(targetDeviceName) + " for a few seconds...");

  // Initialize the BLE device
  BLEDevice::init("");
  
  // Start scanning for BLE devices
  BLEScan* pBLEScan = BLEDevice::getScan(); 
  pBLEScan->setActiveScan(true); 
  BLEScanResults foundDevices = pBLEScan->start(3); // Scan for 3 seconds

  //Serial.print("Devices found: ");
  //Serial.println(foundDevices.getCount());
  //Serial.println("----------------------------");

  bool deviceConnected = false;

  for (int i = 0; i < foundDevices.getCount(); i++) {
    BLEAdvertisedDevice device = foundDevices.getDevice(i);
    if (device.haveName() && device.getName().compare(targetDeviceName.c_str()) == 0) {
      if (serial_debug_output_bool) Serial.println("Found the Peripheral/Slave ESP32!");

      BLEClient* pClient = BLEDevice::createClient();
      if (pClient->connect(&device)) {
        if (serial_debug_output_bool) Serial.println("Connected to the Peripheral/Slave ESP32");

        BLERemoteService* pRemoteService = pClient->getService(serviceUUID);
        if (pRemoteService != nullptr) {
          pTxCharacteristic = pRemoteService->getCharacteristic(charUUID);

          if (pTxCharacteristic != nullptr && pTxCharacteristic->canWrite()) {
            deviceConnected = true;
            //Serial.println("Successfully connected to the service and characteristic on the slave ESP32");
            break; // Exit the loop as the device is connected
          } else {
            //Serial.println("Characteristic not found or not writable");
          }
        } else {
          //Serial.println("Service not found");
        }
      } else {
        0;
        //if (serial_debug_output_bool) Serial.println("Failed to connect");
      }
    }
  }

  if (!deviceConnected) {
    if (serial_debug_output_bool) Serial.println("Failed to connect to the Peripheral/Slave ESP32. Please restart to try again.");
    if (serial_debug_output_bool) Serial.println("Also, check that the peripheral ESP32's code - its BLE_Mode_boolean variable must be set to true to enable BLE connection.");
    //output_text = "BLE connect failed, restart the Client/Master ESP32 to try connecting again...";
    while (true) {
      delay(1000); // Keep the program in an infinite loop if not connected
    }
  }
  
  output_text = "BLE connect success!";
  if (serial_debug_output_bool) Serial.println(output_text);
  output_text = "Connected to " + String(targetDeviceName);
  if (serial_debug_output_bool) Serial.println(output_text);
  delay(500);

  if (serial_debug_output_bool) Serial.println("Initialization complete.");
  delay(500);

}

void loop() {
  //Read the 3 x joysticks, and send out the readings as one comma-delimited string over BLE
  //to the Peripheral/Slave ESP32.
  read_joysticks();
  BLE_data_to_send = String(joystick_value_x) + "," + String(joystick_value_y) + "," + String(joystick_value_z);
  if (pTxCharacteristic != nullptr) {
    if (serial_debug_output_bool) Serial.println("Sending: " + BLE_data_to_send);
    pTxCharacteristic->writeValue(BLE_data_to_send.c_str(), BLE_data_to_send.length());
  }
}