【花雕学编程】Arduino动手做（256）---AHT20 模块在 OLED 屏幕 (SSD1306) 以及串口监视器进行显示温湿度 简单

/*
  【Arduino】189种传感器模块系列实验（资料代码+仿真编程+图形编程）
  实验二百五十六：AHT20 温湿度传感器模块 高精度湿度探头 DHT11升级款I2C
  项目之四：在 OLED 屏幕 (SSD1306) 以及串口监视器进行显示温湿度
*/

// 引入 SSD1306 OLED 显示库
#include "ssd1306.h"
// 引入 Adafruit AHTX0 传感器库
#include <Adafruit_AHTX0.h>

// 创建 AHT10/AHT20 传感器对象
Adafruit_AHTX0 aht;

void setup() {
  Serial.begin(9600); // 初始化串口通信
  Serial.println("AHT20 test");

  // 检测 AHT20 传感器是否正确连接
  if (!aht.begin()) {
    Serial.println("Could not find AHT? Check wiring"); // 显示错误信息
    while (1) delay(10); // 停止执行，防止错误数据读取
  }
  Serial.println("AHT10 or AHT20 found");

  // 初始化 OLED 显示屏
  ssd1306_setFixedFont(ssd1306xled_font6x8); // 设置固定字体
  ssd1306_128x64_i2c_init(); // 初始化 SSD1306 (128x64 I2C)
  ssd1306_clearScreen(); // 清空屏幕

  // 在 OLED 屏幕上显示初始化信息
  ssd1306_printFixed(0, 8, "arduino-er exercise", STYLE_NORMAL);
  ssd1306_printFixed(0, 16, "XIAO/ssd1306", STYLE_BOLD);
  ssd1306_printFixed(0, 24, "AHT20 test", STYLE_ITALIC);
  ssd1306_positiveMode(); // 设置 OLED 正显模式

  delay(2000); // 延迟 2 秒，确保 OLED 初始化完成
  ssd1306_clearScreen(); // 清空屏幕，准备显示实时数据
}

void loop() {
  // 创建温湿度数据对象
  sensors_event_t humidity, temp;
  aht.getEvent(&humidity, &temp); // 读取最新温湿度数据

  // 在串口监视器输出温度数据
  Serial.print("Temperature: ");
  Serial.print(temp.temperature);
  Serial.println(" degrees C");

  // 在 OLED 屏幕上显示标题
  ssd1306_printFixed(0, 10, "- AHT20 -", STYLE_BOLD);

  // 格式化温度数据并显示在 OLED 上
  char charTemp[32]; // 存储格式化后的温度字符串
  dtostrf(temp.temperature, 8, 2, charTemp); // 将浮点数转换为字符串
  ssd1306_printFixed(0, 28, "Temperature (C):", STYLE_NORMAL);
  ssd1306_printFixed(80, 36, charTemp, STYLE_NORMAL); // 显示温度数值

  // 在串口监视器输出湿度数据
  Serial.print("Humidity: ");
  Serial.print(humidity.relative_humidity);
  Serial.println("% rH");

  // 格式化湿度数据并显示在 OLED 上
  char charHumi[32]; // 存储格式化后的湿度字符串
  dtostrf(humidity.relative_humidity, 8, 2, charHumi); // 将浮点数转换为字符串
  ssd1306_printFixed(0, 44, "Humidity (% rH):", STYLE_NORMAL);
  ssd1306_printFixed(80, 52, charHumi, STYLE_NORMAL); // 显示湿度数值

  delay(500); // 每 500 毫秒更新一次数据
}