【花雕学编程】Arduino动手做（238）---ESP32 CYD液晶2.8寸开发板显示文本和测试触摸屏 简单

/*
  【Arduino】168种传感器模块系列实验（资料代码+仿真编程+图形编程）
  实验二百三十八：ESP32 CYD开发板WiFi蓝牙2.8寸240*320智能液晶显示屏带触摸屏TFT模块
  项目实验之十七：ESP32 CYD液晶2.8寸开发板显示文本和测试触摸屏
*/

#include <SPI.h>  // 引入SPI库，用于与触摸屏通信
#include <TFT_eSPI.h>  // 引入TFT_eSPI库，用于驱动TFT显示屏
#include <XPT2046_Touchscreen.h>  // 引入XPT2046触摸屏库

TFT_eSPI tft = TFT_eSPI(); // 创建TFT_eSPI对象，用于操作显示屏

// 定义触摸屏的引脚
#define XPT2046_IRQ 36 // 触摸屏中断引脚
#define XPT2046_MOSI 32 // 触摸屏MOSI引脚
#define XPT2046_MISO 39 // 触摸屏MISO引脚
#define XPT2046_CLK 25 // 触摸屏时钟引脚
#define XPT2046_CS 33 // 触摸屏片选引脚

// 创建一个SPI类对象，用于触摸屏通信
SPIClass touchscreenSPI = SPIClass(VSPI); // 使用VSPI端口
XPT2046_Touchscreen touchscreen(XPT2046_CS, XPT2046_IRQ); // 创建XPT2046触摸屏对象

#define SCREEN_WIDTH 320 // 显示屏宽度
#define SCREEN_HEIGHT 240 // 显示屏高度
#define FONT_SIZE 2 // 字体大小

// 存储触摸屏坐标：(x, y) 和压力(z)
int x, y, z;

// 在串口监视器上打印触摸屏信息，包括X、Y和压力(Z)
void printTouchToSerial(int touchX, int touchY, int touchZ) {
  Serial.print("X = ");
  Serial.print(touchX);
  Serial.print(" | Y = ");
  Serial.print(touchY);
  Serial.print(" | Pressure = ");
  Serial.print(touchZ);
  Serial.println();
}

// 在TFT显示屏上打印触摸屏信息，包括X、Y和压力(Z)
void printTouchToDisplay(int touchX, int touchY, int touchZ) {
  // 清空TFT屏幕
  tft.fillScreen(TFT_WHITE);
  tft.setTextColor(TFT_BLACK, TFT_WHITE);  // 设置文本颜色和背景色

  int centerX = SCREEN_WIDTH / 2;
  int textY = 80;
  
  String tempText = "X = " + String(touchX);
  tft.drawCentreString(tempText, centerX, textY, FONT_SIZE);  // 绘制文本

  textY += 20;
  tempText = "Y = " + String(touchY);
  tft.drawCentreString(tempText, centerX, textY, FONT_SIZE);

  textY += 20;
  tempText = "Pressure = " + String(touchZ);
  tft.drawCentreString(tempText, centerX, textY, FONT_SIZE);
}

void setup() {
  Serial.begin(115200);  // 开启串口通信，波特率为115200

  // 初始化触摸屏的SPI通信并启动触摸屏
  touchscreenSPI.begin(XPT2046_CLK, XPT2046_MISO, XPT2046_MOSI, XPT2046_CS);
  touchscreen.begin(touchscreenSPI);
  // 设置触摸屏旋转为横向模式
  // 注意：有些显示屏的触摸屏可能需要设置旋转为3：touchscreen.setRotation(3);
  touchscreen.setRotation(1);

  // 启动TFT显示屏
  tft.init();
  // 设置TFT显示屏旋转为横向模式
  tft.setRotation(1);

  // 清空屏幕，准备写入
  tft.fillScreen(TFT_WHITE);
  tft.setTextColor(TFT_BLACK, TFT_WHITE);  // 设置文本颜色和背景色
  
  // 设置显示中心的X和Y坐标
  int centerX = SCREEN_WIDTH / 2;
  int centerY = SCREEN_HEIGHT / 2;

  tft.drawCentreString("Hello, world!", centerX, 30, FONT_SIZE);  // 绘制文本
  tft.drawCentreString("Touch screen to test", centerX, centerY, FONT_SIZE);
}

void loop() {
  // 检查触摸屏是否被触摸，并在TFT显示屏和串口监视器上打印X、Y和压力(Z)信息
  if (touchscreen.tirqTouched() && touchscreen.touched()) {
    // 获取触摸屏坐标点
    TS_Point p = touchscreen.getPoint();
    // 使用map函数校准触摸屏坐标点到正确的宽度和高度
    x = map(p.x, 200, 3700, 1, SCREEN_WIDTH);
    y = map(p.y, 240, 3800, 1, SCREEN_HEIGHT);
    z = p.z;

    printTouchToSerial(x, y, z);  // 打印到串口监视器
    printTouchToDisplay(x, y, z);  // 打印到TFT显示屏

    delay(100);  // 延时100毫秒
  }
}