Beetle 树莓派RP2350 高精度电压监测系统 简单

float readPrecisionVoltage() {
  // 超采样：8次采样取平均，降低噪声
  uint32_t rawSum = 0;
  for(int i=0; i<8; i++) {
    rawSum += analogRead(ADC_PIN);
    delayMicroseconds(150); // 避免采样间隔过短
  }
  float newSample = rawSum / 8.0;

  // 滑动窗口滤波：32点移动平均
  filter.sum -= filter.buffer[filter.index];
  filter.buffer[filter.index] = newSample;
  filter.sum += newSample;
  filter.index = (filter.index + 1) % SAMPLE_WINDOW;

  // 电压计算
  float dividerVoltage = (filter.sum / SAMPLE_WINDOW * VREF_ACTUAL) / 4095.0;
  return dividerVoltage * (R1 + R2) / R2 * CAL_FACTOR;
}


超采样（Oversampling）：8次采样取平均，利用统计特性抑制随机噪声。
滑动窗口滤波：32个样本的移动平均，消除短期波动，提升稳定性。
分压计算：通过电阻分压公式 V_actual = V_adc * (R1+R2)/R2，结合校准因子 CAL_FACTOR 修正硬件误差。

void updateOLED(float voltage) {
  u8g2.clearBuffer();
  u8g2.setFont(u8g2_font_ncenB14_tr);
  u8g2.setCursor(0, 30);
  u8g2.print("VOL:");
  u8g2.print(voltage, 2); // 显示2位小数
  u8g2.print("V");
  // 状态栏显示项目名称
  u8g2.setFont(u8g2_font_6x10_tr);
  u8g2.setCursor(0, 63);
  u8g2.print("RP2350 ADC");
  u8g2.sendBuffer();
}

使用U8g2库驱动128×64 OLED，支持自定义字体和动态刷新。
双字体设计：主界面大字体突出电压值，底部状态栏显示项目标识。

#include <Arduino.h>
#include <SoftwareSerial.h>
#include <U8g2lib.h>  // 添加OLED库

// 硬件配置
const int ADC_PIN = 27;          
const float R1 = 99200.0;        
const float R2 = 197200.0;       
const float VREF_ACTUAL = 3.312; 
const int SAMPLE_WINDOW = 32;    
const float CAL_FACTOR = 1.063;  

// 初始化OLED对象（硬件I2C，D5=SCL, D4=SDA）
U8G2_SSD1306_128X64_NONAME_F_HW_I2C u8g2(
  U8G2_R0, 
  /* reset=*/ U8X8_PIN_NONE, 
  /* clock=*/ 5,  // D5引脚作为SCL
  /* data=*/ 4    // D4引脚作为SDA
);

SoftwareSerial hardwareSerial(9, 8);  // 硬件串口D8/D9

// 改进型滤波结构
struct {
  float buffer[SAMPLE_WINDOW] = {0};
  uint8_t index = 0;
  float sum = 0;
} filter;

float readPrecisionVoltage() {
  // 移除旧样本
  filter.sum -= filter.buffer[filter.index];
  
  // 超采样采集（8次采样取平均）
  uint32_t rawSum = 0;
  for(int i=0; i<8; i++){
    rawSum += analogRead(ADC_PIN);
    delayMicroseconds(150);
  }
  float newSample = rawSum / 8.0;

  // 更新滤波窗口
  filter.buffer[filter.index] = newSample;
  filter.sum += newSample;
  filter.index = (filter.index + 1) % SAMPLE_WINDOW;

  // 计算分压电压
  float dividerVoltage = (filter.sum / SAMPLE_WINDOW * VREF_ACTUAL) / 4095.0;
  
  // 计算实际电压
  return dividerVoltage * (R1 + R2) / R2 * CAL_FACTOR;
}

void updateOLED(float voltage) {
  u8g2.clearBuffer();           // 清除缓冲区
  u8g2.setFont(u8g2_font_ncenB14_tr); 
  
  // 绘制电压值
  u8g2.setCursor(0, 30);
  u8g2.print("VOL:");
  u8g2.print(voltage, 2);
  u8g2.print("V");

  // 绘制状态栏
  u8g2.setFont(u8g2_font_6x10_tr);
  u8g2.setCursor(0, 63);
  u8g2.print("RP2350 ADC");
  
  u8g2.sendBuffer();  // 发送显示数据
}

void setup() {
  Serial.begin(115200);
  hardwareSerial.begin(115200);
  analogReadResolution(12);       

  // 初始化OLED
  u8g2.begin();
  u8g2.setContrast(150);  // 设置对比度
  u8g2.clearDisplay();
  u8g2.setFlipMode(0);    // 根据需要调整显示方向
}

void loop() {
  static uint32_t lastPrint = 0;
  
  if(millis() - lastPrint >= 1000) {
    float voltage = readPrecisionVoltage();
    
    // 串口输出
    char report[40];
    snprintf(report, sizeof(report), "VOL:%.3f RAW:%.1f", voltage, filter.sum/SAMPLE_WINDOW);
    Serial.println(report);
    hardwareSerial.println(report);

    // 更新OLED显示
    updateOLED(voltage);
    
    lastPrint = millis();
  }
}