【花雕学编程】Arduino动手做（232）---综合采集ESP32-S3 N16R8 CAM的各种参数并串口输出 简单

/*
  【Arduino】168种传感器模块系列实验（资料代码+仿真编程+图形编程）
   实验二百三十二：ESP32-S3 WROOM N16R8 CAM开发板WiFi+蓝牙模块
   OV2640/5640摄像头模组
  {花雕动手做}实验之五：综合采集ESP32-S3 N16R8 CAM的各种参数并串口输出
*/

#include <WiFi.h>
#include <esp_wifi.h>
#include <esp_system.h>
#include <esp_chip_info.h>
#include <esp_spi_flash.h>

// WiFi网络信息
const char* ssid = "zhz3";
const char* password = "z156721";

void setup() {
  // 初始化串口
  Serial.begin(115200);
  Serial.println(" ");
  Serial.println("ESP32-S3 N16R8 CAM 准备就绪！");
  Serial.println(" ");
  delay(1000);

  // 连接WiFi
  WiFi.begin(ssid, password);
  Serial.print("连接到WiFi");
  while (WiFi.status() != WL_CONNECTED) {
    delay(500);
    Serial.print("...");
  }
  Serial.println(" 接通");

  // 打印WiFi信息
  Serial.print("IP地址: ");
  Serial.println(WiFi.localIP());
  Serial.print("信号强度 (RSSI): ");
  Serial.println(WiFi.RSSI());

  // 打印芯片信息
  esp_chip_info_t chip_info;
  esp_chip_info(&chip_info);
  Serial.printf("ESP32 芯片型号: %d\n", chip_info.model);
  Serial.printf("芯核数量: %d\n", chip_info.cores);
  Serial.printf("芯片修订版本: %d\n", chip_info.revision);

  // 打印CPU频率
  Serial.printf("CPU 频率: %d MHz\n", getCpuFrequencyMhz());

  // 打印内存信息
  Serial.printf("当前内存大小: %d bytes\n", esp_get_free_heap_size());
  Serial.printf("最小可用堆内存大小: %d bytes\n", esp_get_minimum_free_heap_size());

  // 打印芯片温度
  Serial.printf("芯片温度: %.2f°C\n", temperatureRead());

  // 获取并打印芯片MAC地址
  uint64_t chipid = ESP.getEfuseMac();
  Serial.printf("芯片MAC地址: %04X%08X\n", (uint16_t)(chipid >> 32), (uint32_t)chipid);

  // 打印芯片ID数字形式
  uint32_t chipId = 0;
  for (int i = 0; i < 17; i = i + 8) {
    chipId |= ((chipid >> (40 - i)) & 0xff) << i;
  }
  Serial.printf("芯片ID : %u\n", chipId);

  // 打印芯片架构信息
  Serial.printf("芯片架构: %s\n", CONFIG_IDF_TARGET);

  // 打印芯片复位原因
  esp_reset_reason_t reset_reason = esp_reset_reason();
  Serial.printf("复位原因: %d\n", reset_reason);

  // 打印WiFi模式
  wifi_mode_t mode;
  esp_wifi_get_mode(&mode);
  Serial.printf("WiFi模式: %d\n", mode);

  // 打印WiFi信道
  uint8_t primaryChan;
  wifi_second_chan_t secondChan;
  esp_wifi_get_channel(&primaryChan, &secondChan);
  Serial.printf("WiFi信道: %d\n", primaryChan);

  // 打印WiFi传输功率
  int8_t power;
  esp_wifi_get_max_tx_power(&power);
  Serial.printf("WiFi传输功率: %d dBm\n", power);
}

void loop() {
  // 在这里可以添加其他测试代码
  delay(10000); // 每10秒打印一次
}