发现

 DF创客社区 产品资料库 DF创客商城
回到首页 返回首页
回到顶部 回到顶部
返回上一页 返回上一页

【雕爷学编程】Arduino动手做（95）---GY9960手势传感器模块5 中等

头像 驴友花雕 2023.07.27 116 1

37款传感器与执行器的提法，在网络上广泛流传，其实Arduino能够兼容的传感器模块肯定是不止这37种的。鉴于本人手头积累了一些传感器和执行器模块，依照实践出真知（一定要动手做）的理念，以学习和交流为目的，这里准备逐一动手尝试系列实验，不管成功（程序走通）与否，都会记录下来—小小的进步或是搞不掂的问题，希望能够抛砖引玉。

 

【Arduino】168种传感器模块系列实验（资料代码+仿真编程+图形编程）
实验九十五：APDS-9960 GY-9960-3.3 RGB红外手势传感器 方向识别模块
 

5.11-01.jpg
5.11-02.jpg

【Arduino】168种传感器模块系列实验（资料代码+仿真编程+图形编程）
实验九十五：APDS-9960 GY-9960-3.3 RGB红外手势传感器 方向识别模块
程序六：计算滑动方向（上、下、左、右）并显示在串口上
（1）Arduino参考开源代码

 

代码
/*
  【Arduino】168种传感器模块系列实验（资料代码+仿真编程+图形编程）
  程序六：计算滑动方向（上、下、左、右）并显示在串口上
  注：设备的 I2C 地址为 0x39
*/

#include <Wire.h>

#include <SparkFun_APDS9960.h>//导入9960驱动库

// 引脚
#define APDS9960_INT    2 // 中断引脚为D2

// 常量

// 全局变量
SparkFun_APDS9960 apds = SparkFun_APDS9960();
int isr_flag = 0;

void setup() {

  // 设置中断引脚为输入
  pinMode(APDS9960_INT, INPUT);

  //初始化串口
  Serial.begin(9600);

  Serial.println();
  Serial.println(F("--------------------------------"));
  Serial.println(F("     APDS-9960 - 手势测试"));
  Serial.println(F("--------------------------------"));

 //初始化中断服务程序
  attachInterrupt(0, interruptRoutine, FALLING);

  // 初始化 APDS-9960（配置 I2C 和初始值）
  if ( apds.init() ) {
    Serial.println(F("APDS-9960 初始化完成"));
  } else {
    Serial.println(F("APDS-9960 初始化期间出现问题！"));
  }

  // 开始运行 APDS-9960 手势传感器引擎
  if ( apds.enableGestureSensor(true) ) {
    Serial.println(F("手势传感器正在运行"));
  } else {
    Serial.println(F("手势传感器初始化过程中出现问题！"));
  }
}

void loop() {
  if ( isr_flag == 1 ) {
    detachInterrupt(0);
    handleGesture();
    isr_flag = 0;
    attachInterrupt(0, interruptRoutine, FALLING);
  }
}

void interruptRoutine() {
  isr_flag = 1;
}

void handleGesture() {
  if ( apds.isGestureAvailable() ) {
switch ( apds.readGesture() ) {

      case DIR_UP:
        Serial.println("向上");
        break;
      case DIR_DOWN:
        Serial.println("向下");
        break;
      case DIR_LEFT:
        Serial.println("向左");
        break;
      case DIR_RIGHT:
        Serial.println("向右");
        break;
      case DIR_NEAR:
        Serial.println("靠近");
        break;
      case DIR_FAR:
        Serial.println("远离");
        break;
      default:
        Serial.println("无动作");
    }
  }
}

（2）实验串口返回情况

 

（3）实验说明

a重要提示：APDS-9960 只能接受 3.3V！

b要执行 “靠近” 手势，请握住您的手远高于传感器并将其移近传感器（在 2

英寸）。握住你的手至少 1 秒钟然后移动它离开。

c要执行 “远离” 手势，请将您的手握在距离目标 2 英寸的范围内传感器至少 1 秒钟，然后将其移到上方（从范围）的传感器。


 

5.11-22.jpg

【Arduino】168种传感器模块系列实验（资料代码+仿真编程+图形编程）
实验九十五：APDS-9960 GY-9960-3.3 RGB红外手势传感器 方向识别模块
程序七：轮询传感器环境光和颜色级别，并显示在串口上
（1）Arduino参考开源代码
 

 

代码
/*
  【Arduino】168种传感器模块系列实验（资料代码+仿真编程+图形编程）
  程序七：轮询传感器环境光和颜色级别，并显示在串口上
  注：设备的 I2C 地址为 0x39
*/

#include <Wire.h>
#include <SparkFun_APDS9960.h>//导入9960驱动库

// 全局变量
SparkFun_APDS9960 apds = SparkFun_APDS9960();
uint16_t ambient_light = 0;
uint16_t red_light = 0;
uint16_t green_light = 0;
uint16_t blue_light = 0;

void setup() {
  //初始化串口
  Serial.begin(9600);
  Serial.println();
  Serial.println(F("--------------------------------"));
  Serial.println(F("      APDS-9960 - 颜色传感器"));
  Serial.println(F("--------------------------------"));

  // 初始化 APDS-9960（配置 I2C 和初始值）
  if ( apds.init() ) {
    Serial.println(F("APDS-9960 初始化完成"));
  } else {
    Serial.println(F("APDS-9960 初始化期间出现问题！"));
  }

  // 开始运行 APDS-9960 光传感器（无中断）
  if ( apds.enableLightSensor(false) ) {
    Serial.println(F("光传感器正在运行"));
  } else {
    Serial.println(F("光传感器初始化过程中出现问题！"));
  }

  // 等待初始化和校准完成
  delay(500);
}

void loop() {
  // 读取光照水平（环境、红色、绿色、蓝色）
  if (  !apds.readAmbientLight(ambient_light) ||
        !apds.readRedLight(red_light) ||
        !apds.readGreenLight(green_light) ||
        !apds.readBlueLight(blue_light) ) {
    Serial.println("读取光值错误");
  } else {
    Serial.print("环境：");
    Serial.print(ambient_light);
    Serial.print(" 红色：");
    Serial.print(red_light);
    Serial.print(" 绿色：");
    Serial.print(green_light);
    Serial.print(" 蓝色： ");
    Serial.println(blue_light);
  }

  // 在下一次读取前等待 1 秒
  delay(1000);
}

（2）实验串口返回情况

 

5.11-23.jpg

【Arduino】168种传感器模块系列实验（资料代码+仿真编程+图形编程）
 实验九十五：APDS-9960 GY-9960-3.3 RGB红外手势传感器 方向识别模块
 程序八：测试 APDS-9960 的环境光中断能力
（1）Arduino参考开源代码
 

 

代码
/*
  【Arduino】168种传感器模块系列实验（资料代码+仿真编程+图形编程）
  程序八：测试 APDS-9960 的环境光中断能力
  注：设备的 I2C 地址为 0x39
*/

#include <Wire.h>
#include <SparkFun_APDS9960.h>//导入9960驱动库

// 引脚
#define APDS9960_INT    2  //中断引脚为D2
#define LED_PIN         13 //显示中断的 LED 接D13

// 常量
#define LIGHT_INT_HIGH  1000 // 中断的高亮度
#define LIGHT_INT_LOW   10   // 低亮度中断

// 全局变量
SparkFun_APDS9960 apds = SparkFun_APDS9960();
uint16_t ambient_light = 0;
uint16_t red_light = 0;
uint16_t green_light = 0;
uint16_t blue_light = 0;
int isr_flag = 0;
uint16_t threshold = 0;

void setup() {
  //设置 LED 为输出
  pinMode(LED_PIN, OUTPUT);
  pinMode(APDS9960_INT, INPUT);

  //初始化串口
  Serial.begin(9600);
  Serial.println();
  Serial.println(F("-------------------------------------"));
  Serial.println(F("         APDS-9960 - 光中断 "));
  Serial.println(F("-------------------------------------"));

  //初始化中断服务程序
  attachInterrupt(0, interruptRoutine, FALLING);

  //初始化 APDS-9960（配置 I2C 和初始值）
  if ( apds.init() ) {
    Serial.println(F("APDS-9960 初始化完成"));
  } else {
    Serial.println(F("APDS-9960 初始化期间出现问题！"));
  }

  //设置高低中断阈值
  if ( !apds.setLightIntLowThreshold(LIGHT_INT_LOW) ) {
    Serial.println(F("写入低阈值错误"));
  }
  if ( !apds.setLightIntHighThreshold(LIGHT_INT_HIGH) ) {
    Serial.println(F("写入高阈值错误"));
  }

  // 开始运行 APDS-9960 光传感器（无中断）
  if ( apds.enableLightSensor(false) ) {
    Serial.println(F("光传感器正在运行"));
  } else {
    Serial.println(F("光传感器初始化过程中出现问题！"));
  }

  /// 读取高低中断阈值
  if ( !apds.getLightIntLowThreshold(threshold) ) {
    Serial.println(F("读取低阈值错误"));
  } else {
    Serial.print(F("低阈值："));
    Serial.println(threshold);
  }
  if ( !apds.getLightIntHighThreshold(threshold) ) {
    Serial.println(F("读取高阈值错误"));
  } else {
    Serial.print(F("高阈值："));
    Serial.println(threshold);
  }

  /// 启用中断
  if ( !apds.setAmbientLightIntEnable(1) ) {
    Serial.println(F("错误启用中断"));
  }

  /// 等待初始化和校准完成
  delay(500);
}

void loop() {
  // 如果发生中断，打印出光照水平
  if ( isr_flag == 1 ) {

    // 读取光照水平（环境、红色、绿色、蓝色）并打印
    if (  !apds.readAmbientLight(ambient_light) ||
          !apds.readRedLight(red_light) ||
          !apds.readGreenLight(green_light) ||
          !apds.readBlueLight(blue_light) ) {
      Serial.println("读取光值错误");
    } else {
      Serial.print("中断！环境光： ");
      Serial.print(ambient_light);
      Serial.print(" R: ");
      Serial.print(red_light);
      Serial.print(" G: ");
      Serial.print(green_light);
      Serial.print(" B: ");
      Serial.println(blue_light);
    }

    // 点亮 LED 半秒
    digitalWrite(LED_PIN, HIGH);
    delay(500);
    digitalWrite(LED_PIN, LOW);

    // 重置标志并清除 APDS-9960 中断（重要！）
    isr_flag = 0;
    if ( !apds.clearAmbientLightInt() ) {
      Serial.println("错误清除中断");
    }

  }
}

void interruptRoutine() {
  isr_flag = 1;
}

（2）实验说明：测试 APDS-9960 的环境光中断能力。通过 I2C 配置 APDS-9960 并等待外部根据高光或低光条件中断。尝试覆盖用手或将传感器靠近明亮的光源。您可能需要调整 LIGHT_INT_HIGH和 LIGHT_INT_LOW 值以使中断正常工作。

 

 

（3）实验串口返回情况

 

5.11-24.jpg

（4）实验场景图（高亮度中断）

 

5.11-25.jpg

Makelog作者原创文章，未经授权禁止转载。
#Arduino#机器人#物联网#雕爷学编程#Arduino动手做#开源硬件#创客传感器#GY9960手势传感器模块

评论

user-avatar
  • 9mm

    9mm2023.08.08

    666

    0
    驴友花雕
    驴友花雕2019.05.06
    icon
    创造力47274
    icon
    项目文章1423

    爱好中国极地探险，二次徒步穿越雅鲁藏布江大峡谷核心无人区域，成功穿越了中国三大沙漠、四大无人区及三江源等中国境内最困难的地方。攀登三座八千米级雪山，组织驼峰搜寻队二次深入高黎贡山核心无人区搜寻驼峰航线坠机，骑行美国66号公路徒步北极等。完成十余项极地摄影专题，累计拍摄相关照片近十万张，在重庆科技馆举办过《花雕中国极地摄影展》。中国探险协会理事，入选“中国国家旅游首席旅行家”、《中国十大徒步人物》和《中国当代徐霞客》。

    icon 他的勋章
      展开更多

      你可能感兴趣的