【花雕动手做】基于 Arduino 的机器人 OLED 眼睛动画：呈现多样情绪，增强交互魅力 简单

/*
  【花雕动手做】为 Arduino 机器人创建迷人的 OLED 眼睛动画！
   实验项目之二：OLED 眼睛：呈现多样情绪，增强交互魅力
*/

#include <SPI.h>                // 引入SPI通信库，用于支持SPI协议
#include <Wire.h>               // 引入I2C通信库，用于支持I2C协议
#include <Adafruit_GFX.h>       // 引入Adafruit图形库，提供基本图形绘制功能
#include <Adafruit_SSD1306.h>   // 引入Adafruit SSD1306 OLED屏幕驱动库

#define SCREEN_WIDTH 128        // 定义OLED屏幕的宽度为128像素
#define SCREEN_HEIGHT 64        // 定义OLED屏幕的高度为64像素
#define OLED_RESET -1           // 定义OLED复位引脚为-1（表示共享Arduino复位引脚）
#define SCREEN_ADDRESS 0x3C     // 定义OLED屏幕的I2C地址为0x3C（根据屏幕型号选择）

Adafruit_SSD1306 display(SCREEN_WIDTH, SCREEN_HEIGHT, &Wire, OLED_RESET);  // 创建SSD1306屏幕对象，使用I2C通信

int demo_mode = 1;              // 定义演示模式标志，1表示循环播放动画
static const int max_animation_index = 8;  // 定义最大动画索引为8
int current_animation_index = 0;  // 定义当前动画索引为0

int ref_eye_height = 40;        // 定义参考眼睛高度为40像素
int ref_eye_width = 40;         // 定义参考眼睛宽度为40像素
int ref_space_between_eye = 10; // 定义两只眼睛之间的间距为10像素
int ref_corner_radius = 10;     // 定义眼睛圆角半径为10像素

int left_eye_height = ref_eye_height;  // 定义左眼当前高度为参考高度
int left_eye_width = ref_eye_width;    // 定义左眼当前宽度为参考宽度
int left_eye_x = 32;                   // 定义左眼X坐标为32
int left_eye_y = 32;                   // 定义左眼Y坐标为32
int right_eye_x = 32 + ref_eye_width + ref_space_between_eye;  // 定义右眼X坐标为左眼X坐标加上眼睛宽度和间距
int right_eye_y = 32;                   // 定义右眼Y坐标为32
int right_eye_height = ref_eye_height;  // 定义右眼当前高度为参考高度
int right_eye_width = ref_eye_width;    // 定义右眼当前宽度为参考宽度

void draw_eyes(bool update = true) {  // 定义绘制眼睛函数，update参数控制是否更新屏幕
    display.clearDisplay();           // 清空屏幕
    int x = int(left_eye_x - left_eye_width / 2);  // 计算左眼的左上角X坐标
    int y = int(left_eye_y - left_eye_height / 2); // 计算左眼的左上角Y坐标
    display.fillRoundRect(x, y, left_eye_width, left_eye_height, ref_corner_radius, SSD1306_WHITE);  // 绘制左眼
    x = int(right_eye_x - right_eye_width / 2);    // 计算右眼的左上角X坐标
    y = int(right_eye_y - right_eye_height / 2);   // 计算右眼的左上角Y坐标
    display.fillRoundRect(x, y, right_eye_width, right_eye_height, ref_corner_radius, SSD1306_WHITE);  // 绘制右眼
    if (update) {  // 如果update为true
        display.display();  // 更新屏幕显示
    }
}

void center_eyes(bool update = true) {  // 定义将眼睛居中函数，update参数控制是否更新屏幕
    left_eye_height = ref_eye_height;  // 重置左眼高度为参考高度
    left_eye_width = ref_eye_width;    // 重置左眼宽度为参考宽度
    right_eye_height = ref_eye_height; // 重置右眼高度为参考高度
    right_eye_width = ref_eye_width;   // 重置右眼宽度为参考宽度
    left_eye_x = SCREEN_WIDTH / 2 - ref_eye_width / 2 - ref_space_between_eye / 2;  // 计算左眼X坐标
    left_eye_y = SCREEN_HEIGHT / 2;    // 计算左眼Y坐标
    right_eye_x = SCREEN_WIDTH / 2 + ref_eye_width / 2 + ref_space_between_eye / 2;  // 计算右眼X坐标
    right_eye_y = SCREEN_HEIGHT / 2;   // 计算右眼Y坐标
    draw_eyes(update);  // 调用绘制眼睛函数
}

void blink(int speed = 12) {  // 定义眨眼函数，speed参数控制眨眼速度
    draw_eyes();  // 绘制眼睛
    for (int i = 0; i < 3; i++) {  // 循环3次，模拟眼睛闭合
        left_eye_height -= speed;  // 左眼高度减小
        right_eye_height -= speed; // 右眼高度减小
        draw_eyes();  // 绘制眼睛
        delay(1);     // 延迟1毫秒
    }
    for (int i = 0; i < 3; i++) {  // 循环3次，模拟眼睛睁开
        left_eye_height += speed;  // 左眼高度增加
        right_eye_height += speed; // 右眼高度增加
        draw_eyes();  // 绘制眼睛
        delay(1);     // 延迟1毫秒
    }
}

void sleep() {  // 定义睡眠函数
    left_eye_height = 2;  // 左眼高度设置为2像素
    right_eye_height = 2; // 右眼高度设置为2像素
    draw_eyes(true);      // 绘制眼睛并更新屏幕
}

void wakeup() {  // 定义唤醒函数
    sleep();  // 调用睡眠函数
    for (int h = 0; h <= ref_eye_height; h += 2) {  // 循环增加眼睛高度
        left_eye_height = h;  // 左眼高度增加
        right_eye_height = h; // 右眼高度增加
        draw_eyes(true);      // 绘制眼睛并更新屏幕
    }
}

void happy_eye() {  // 定义开心眼睛函数
    center_eyes(false);  // 将眼睛居中，但不更新屏幕
    int offset = ref_eye_height / 2;  // 定义偏移量为眼睛高度的一半
    for (int i = 0; i < 10; i++) {  // 循环10次，模拟开心表情
        display.fillTriangle(left_eye_x - left_eye_width / 2 - 1, left_eye_y + offset, left_eye_x + left_eye_width / 2 + 1, left_eye_y + 5 + offset, left_eye_x - left_eye_width / 2 - 1, left_eye_y + left_eye_height + offset, SSD1306_BLACK);  // 绘制左眼下方的倒三角形
        display.fillTriangle(right_eye_x + right_eye_width / 2 + 1, right_eye_y + offset, right_eye_x - left_eye_width / 2 - 1, right_eye_y + 5 + offset, right_eye_x + right_eye_width / 2 + 1, right_eye_y + right_eye_height + offset, SSD1306_BLACK);  // 绘制右眼下方的倒三角形
        offset -= 2;  // 偏移量减少
        display.display();  // 更新屏幕
        delay(1);     // 延迟1毫秒
    }
    display.display();  // 更新屏幕
    delay(1000);       // 延迟1秒
}

void saccade(int direction_x, int direction_y) {  // 定义快速眼动函数
    int direction_x_movement_amplitude = 8;  // 定义X方向移动幅度
    int direction_y_movement_amplitude = 6;  // 定义Y方向移动幅度
    int blink_amplitude = 8;                // 定义眨眼幅度
    for (int i = 0; i < 1; i++) {  // 循环1次，模拟眼睛快速移动
        left_eye_x += direction_x_movement_amplitude * direction_x;  // 左眼X坐标移动
        right_eye_x += direction_x_movement_amplitude * direction_x; // 右眼X坐标移动
        left_eye_y += direction_y_movement_amplitude * direction_y;  // 左眼Y坐标移动
        right_eye_y += direction_y_movement_amplitude * direction_y; // 右眼Y坐标移动
        right_eye_height -= blink_amplitude;  // 右眼高度减小
        left_eye_height -= blink_amplitude;   // 左眼高度减小
        draw_eyes();  // 绘制眼睛
        delay(1);     // 延迟1毫秒
    }
    for (int i = 0; i < 1; i++) {  // 循环1次，恢复眼睛状态
        left_eye_x += direction_x_movement_amplitude * direction_x;  // 左眼X坐标移动
        right_eye_x += direction_x_movement_amplitude * direction_x; // 右眼X坐标移动
        left_eye_y += direction_y_movement_amplitude * direction_y;  // 左眼Y坐标移动
        right_eye_y += direction_y_movement_amplitude * direction_y; // 右眼Y坐标移动
        right_eye_height += blink_amplitude;  // 右眼高度增加
        left_eye_height += blink_amplitude;   // 左眼高度增加
        draw_eyes();  // 绘制眼睛
        delay(1);     // 延迟1毫秒
    }
}

void move_big_eye(int direction) {  // 定义大眼睛移动函数
    int direction_oversize = 1;     // 定义眼睛放大幅度
    int direction_movement_amplitude = 2;  // 定义移动幅度
    int blink_amplitude = 5;       // 定义眨眼幅度
    for (int i = 0; i < 3; i++) {  // 循环3次，模拟眼睛移动和放大
        left_eye_x += direction_movement_amplitude * direction;  // 左眼X坐标移动
        right_eye_x += direction_movement_amplitude * direction; // 右眼X坐标移动
        right_eye_height -= blink_amplitude;  // 右眼高度减小
        left_eye_height -= blink_amplitude;   // 左眼高度减小
        if (direction > 0) {  // 如果方向为正
            right_eye_height += direction_oversize;  // 右眼高度增加
            right_eye_width += direction_oversize;   // 右眼宽度增加
        } else {  // 如果方向为负
            left_eye_height += direction_oversize;   // 左眼高度增加
            left_eye_width += direction_oversize;    // 左眼宽度增加
        }
        draw_eyes();  // 绘制眼睛
        delay(1);     // 延迟1毫秒
    }
    for (int i = 0; i < 3; i++) {  // 循环3次，恢复眼睛状态
        left_eye_x += direction_movement_amplitude * direction;  // 左眼X坐标移动
        right_eye_x += direction_movement_amplitude * direction; // 右眼X坐标移动
        right_eye_height += blink_amplitude;  // 右眼高度增加
        left_eye_height += blink_amplitude;   // 左眼高度增加
        if (direction > 0) {  // 如果方向为正
            right_eye_height += direction_oversize;  // 右眼高度增加
            right_eye_width += direction_oversize;   // 右眼宽度增加
        } else {  // 如果方向为负
            left_eye_height += direction_oversize;   // 左眼高度增加
            left_eye_width += direction_oversize;    // 左眼宽度增加
        }
        draw_eyes();  // 绘制眼睛
        delay(1);     // 延迟1毫秒
    }
    delay(1000);  // 延迟1秒
    center_eyes();  // 将眼睛居中
}

void move_right_big_eye() {
    move_big_eye(1);  // 调用 move_big_eye 函数，传入方向参数 1（向右）
}

void move_left_big_eye() {
    move_big_eye(-1); // 调用 move_big_eye 函数，传入方向参数 -1（向左）
}

void launch_animation_with_index(int animation_index) {  // 定义根据动画索引播放动画的函数
    if (animation_index > max_animation_index) {  // 如果动画索引超过最大值
        animation_index = max_animation_index;    // 将动画索引设置为最大值
    }

    switch (animation_index) {  // 根据动画索引选择动画
        case 0:
            wakeup();  // 播放唤醒动画
            break;
        case 1:
            center_eyes(true);  // 播放眼睛居中动画
            break;
        case 2:
            move_right_big_eye();  // 播放右眼放大动画
            break;
        case 3:
            move_left_big_eye();   // 播放左眼放大动画
            break;
        case 4:
            blink(10);  // 播放眨眼动画（速度10）
            break;
        case 5:
            blink(20);  // 播放眨眼动画（速度20）
            break;
        case 6:
            happy_eye();  // 播放开心眼睛动画
            break;
        case 7:
            sleep();  // 播放睡眠动画
            break;
        case 8:
            center_eyes(true);  // 播放眼睛居中动画
            for (int i = 0; i < 20; i++) {  // 随机快速眼动
                int dir_x = random(-1, 2);  // 随机X方向
                int dir_y = random(-1, 2);  // 随机Y方向
                saccade(dir_x, dir_y);      // 播放快速眼动动画
                delay(1);                  // 延迟1毫秒
                saccade(-dir_x, -dir_y);   // 恢复眼睛位置
                delay(1);                  // 延迟1毫秒
            }
            break;
    }
}

void setup() {  // 定义初始化函数
    display.begin(SSD1306_SWITCHCAPVCC, SCREEN_ADDRESS);  // 初始化屏幕
    Serial.begin(115200);  // 初始化串口通信
    display.clearDisplay();  // 清空屏幕
    display.setTextSize(1);  // 设置文本大小为1
    display.setTextColor(SSD1306_WHITE);  // 设置文本颜色为白色
    display.setCursor(0, 0);  // 设置文本起始位置
    display.println(F("Intellar.ca"));  // 显示文本
    display.display();  // 更新屏幕
    delay(2000);  // 延迟2秒
    sleep();  // 调用睡眠函数
    delay(2000);  // 延迟2秒
}

void loop() {  // 定义主循环函数
    if (demo_mode == 1) {  // 如果演示模式为1
        launch_animation_with_index(current_animation_index++);  // 播放当前动画
        if (current_animation_index > max_animation_index) {  // 如果动画索引超过最大值
            current_animation_index = 0;  // 重置动画索引
        }
    }
    if (Serial.available()) {  // 如果串口有数据
        String data = Serial.readString();  // 读取串口数据
        data.trim();  // 去除数据前后空格
        char cmd = data[0];  // 获取命令字符
        if (cmd == 'A') {  // 如果命令为'A'
            demo_mode = 0;  // 关闭演示模式
            String arg = data.substring(1, data.length());  // 获取参数
            int anim = arg.toInt();  // 将参数转换为整数
            launch_animation_with_index(anim);  // 播放指定动画
            Serial.print(cmd);  // 发送命令字符
            Serial.print(arg);  // 发送参数
        }
    }
}